x86/boot: create *.lnk files with linker script

Newer GCC (e.g. gcc version 5.1.1 20150618 (Red Hat 5.1.1-4) (GCC)) does
some code optimizations by creating data sections (e.g. jump addresses
for C switch/case are calculated using data in .rodata section). This
thing is not accepted by *.lnk build recipe which requires that only .text
section lives in output. Potentially we can inhibit this GCC behavior by
using special options, e.g. -fno-tree-switch-conversion. However, this
does not guarantee that in the future new similar optimizations or anything
else which creates not accepted sections will not break our build recipes
again. I do not mention that probably this is not good idea to just disable
random optimizations. So, take over full control on *.lnk linking process
by using linker script and merge all text and data sections into one
.text section.

Additionally, remove .got.plt section which is not used in our final code.

Signed-off-by: Daniel Kiper <daniel.kiper@oracle.com>
Reviewed-by: Jan Beulich <jbeulich@suse.com>

diff --git a/xen/arch/x86/boot/build32.lds b/xen/arch/x86/boot/build32.lds
new file mode 100644 (file)
index 0000000..da35aee
--- /dev/null
+++ b/xen/arch/x86/boot/build32.lds
@@ -0,0 +1,52 @@
+/*
+ * Copyright (c) 2016 Oracle and/or its affiliates. All rights reserved.
+ *
+ * This program is free software; you can redistribute it and/or modify
+ * it under the terms of the GNU General Public License as published by
+ * the Free Software Foundation; either version 2 of the License, or
+ * (at your option) any later version.
+ *
+ * This program is distributed in the hope that it will be useful,
+ * but WITHOUT ANY WARRANTY; without even the implied warranty of
+ * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+ * GNU General Public License for more details.
+ *
+ * You should have received a copy of the GNU General Public License along
+ * with this program.  If not, see <http://www.gnu.org/licenses/>.
+ */
+
+ENTRY(_start)
+
+SECTIONS
+{
+  /* Merge code and data into one section. */
+  .text : {
+        *(.text)
+        *(.text.*)
+        *(.data)
+        *(.data.*)
+        *(.rodata)
+        *(.rodata.*)
+        *(.bss)
+        *(.bss.*)
+  }
+
+  /DISCARD/ : {
+        /*
+         * PIC/PIE executable contains .got.plt section even if it is not linked
+         * with dynamic libraries. In such case it is just placeholder for
+         * _GLOBAL_OFFSET_TABLE_ symbol and .PLT0. .PLT0 is filled by dynamic
+         * linker and our code is not supposed to be loaded by dynamic linker.
+         * So, from our point of view .PLT0 is unused. This means that there is
+         * pretty good chance that we can safely drop .got.plt as a whole here.
+         * Sadly this is not true. _GLOBAL_OFFSET_TABLE_ is used as a reference
+         * for relative addressing (and only for that thing) and ld complains if
+         * we remove .got.plt section here because it cannot find required symbol.
+         * However, _GLOBAL_OFFSET_TABLE_ is no longer needed in final output.
+         * So, drop .got.plt section during conversion to plain binary format.
+         *
+         * Please check build32.mk for more details.
+         */
+        /* *(.got.plt) */
+  }
+}

diff --git a/xen/arch/x86/boot/build32.mk b/xen/arch/x86/boot/build32.mk
index 4a7d3883b9573a238e1a707d9fe54e14d01280b7..39e6453ccb2f0c024f41a0785302d5b93a3dd1de 100644 (file)
--- a/xen/arch/x86/boot/build32.mk
+++ b/xen/arch/x86/boot/build32.mk
@@ -12,20 +12,22 @@ CFLAGS := $(filter-out -flto,$(CFLAGS))
        (od -v -t x $< | tr -s ' ' | awk 'NR > 1 {print s} {s=$$0}' | \
        sed 's/ /,0x/g' | sed 's/,0x$$//' | sed 's/^[0-9]*,/ .long /') >$@
 
+# Drop .got.plt during conversion to plain binary format.
+# Please check build32.lds for more details.
 %.bin: %.lnk
-       $(OBJCOPY) -O binary $< $@
-
-%.lnk: %.o
-       $(OBJDUMP) -h $< | sed -n '/[0-9]/{s,00*,0,g;p;}' |\
+       $(OBJDUMP) -h $< | sed -n '/[0-9]/{s,00*,0,g;p;}' | \
                while read idx name sz rest; do \
                        case "$$name" in \
-                       .data|.data.*|.rodata|.rodata.*|.bss|.bss.*) \
-                               test $$sz != 0 || continue; \
+                       .got.plt) \
+                               test $$sz != 0c || continue; \
                                echo "Error: non-empty $$name: 0x$$sz" >&2; \
                                exit $$(expr $$idx + 1);; \
                        esac; \
                done
-       $(LD) $(LDFLAGS_DIRECT) -N -Ttext 0 -o $@ $<
+       $(OBJCOPY) -O binary -R .got.plt $< $@
+
+%.lnk: %.o
+       $(LD) $(LDFLAGS_DIRECT) -N -T build32.lds -o $@ $<
 
 %.o: %.c
        $(CC) $(CFLAGS) -c -fpic $< -o $@